Разговор

Теперь Вы можете поговорить с любым прохожим, кроме представителей полиции, "Скорой помощи" и пожарных. Для этого нацельтесь на человека и нажмите "Действие". Для завершения разговора нажмите одну из клавиш движения.

//$PLAYER_ACTOR $PLAYER_GROUP
{$CLEO}
0000:
while true
wait 0
    if
    player.Defined(0)
    then   
        if and
        810F: not  player $PLAYER_CHAR wanted_level > 0
        not actor.Driving($PLAYER_ACTOR)
        00E1:   player 0 pressed_key 6
        00E1:   player 0 pressed_key 4
        then
            if or
            02D8:   actor $PLAYER_ACTOR current_weapon == 0
            02D8:   actor $PLAYER_ACTOR current_weapon == 1
            then
                if
                0AD2: 0@ = player $PLAYER_CHAR targeted_actor //IF and SET
                then
                089F: get_actor 0@ pedtype_to 1@
                //080E: get_actor 0@ ped_event_to 2@
                    if and
                    1@ <> 6
                    1@ <> 18
                    1@ <> 19
                    /*2@ <> 36
                    2@ <> 37*/
                    not actor.Driving(0@)
                    0105:   actor $PLAYER_ACTOR near_actor 0@ radius 3.0 3.0 3.0 sphere 0 on_foot
                    then
                    camera.OnPed($PLAYER_ACTOR,65,1)
                    player.CanMove(0,0)
                    0826: enable_hud 0
                    0581: enable_radar 0
                    0677: AS_actor $PLAYER_ACTOR chat_with_actor 0@ lead_speaker_flag 1 unknown_flag 1
                    0677: AS_actor 0@ chat_with_actor $PLAYER_ACTOR lead_speaker_flag 0 unknown_flag 1
                        while true
                        wait 0
                            if or
                            010F:   player 0 wanted_level > 0
                            00E1:   player 0 pressed_key 0
                            00E1:   player 0 pressed_key 1
                            not player.Defined(0)
                            actor.Driving($PLAYER_ACTOR)
                            actor.Dead(0@)
                            actor.Driving(0@)
                            8105:  not actor $PLAYER_ACTOR near_actor 0@ radius 3.0 3.0 3.0 sphere 0 on_foot
                            then
                            0687: clear_actor 0@ task
                            0687: clear_actor $PLAYER_ACTOR task
                            break
                            end
                        end
                    actor.RemoveReferences(0@)
                    camera.Restore()
                    player.CanMove(0,1)
                    0826: enable_hud 1
                    0581: enable_radar 1
                    end
                end
            end
        end
    end
end