Вертолет с охраной

Нажмите "ПриказСтоять"+B(англ), и вдалеке появится вертолет с двумя охранниками. У одного из них АК-47, а другого - винтовка. У них достаточно хорошая точность. Вертолет будет следовать за Вами, а охрана убивать копов и балласов. Чтобы отпустить вертолет, нажмите "Войти в машину". Если убить пилота, вертолет начнет кружиться и упадет.

:Heli01
wait 10
model.Load(#SEASPAR)
model.Load(#FAM1)
model.Load(#FAM2)
model.Load(#AK47)
model.Load(#SNIPER)
038B: load_requested_models

:Heli02
wait 10
if and
Model.Available(#SEASPAR)
model.Available(#FAM1)
model.Available(#FAM2)
model.Available(#AK47)
model.Available(#SNIPER)
player.Defined($PLAYER_CHAR)
not actor.Dead($PLAYER_ACTOR)
jf @Heli02
if and
not actor.Driving($PLAYER_ACTOR)
00E1:   player 0 pressed_key 9
0AB0:  key_pressed 0x42
jf @Heli02
0208: 4@ = random_float_in_ranges -50.0 50.0
04C4: store_coords_to 1@ 2@ 3@ from_actor $PLAYER_ACTOR with_offset -75.0 4@ 300.0
car.Create(5@,#SEASPAR,1@,2@,3@)
02AC: set_car 5@ immunities BP 1 FP 0 EP 0 CP 0 MP 0
0560: create_random_actor_in_car 5@ handle_as 6@
actor.Create(7@,8,#FAM1,1@,2@,3@)
01B2: give_actor 7@ weapon 30 ammo 9999 // Load the weapon model before using this
actor.WeaponAccuracy(7@) = 50.0
actor.Angle(7@) = 180.0
0464: put_actor 7@ into_turret_on_car 5@ at_car_offset 1.0 0.2 0.3 position 0 shooting_angle_limit 360.0 with_weapon 30
actor.Create(8@,8,#FAM2,1@,2@,3@)
01B2: give_actor 8@ weapon 34 ammo 9999 // Load the weapon model before using this
actor.WeaponAccuracy(8@) = 75.0
0464: put_actor 8@ into_turret_on_car 5@ at_car_offset -1.0 0.2 0.3 position 0 shooting_angle_limit 360.0 with_weapon 34
077A: set_actor 7@ acquaintance 4 to_actors_pedtype 6 // see ped.dat
077A: set_actor 8@ acquaintance 4 to_actors_pedtype 6 // see ped.dat
077A: set_actor 7@ acquaintance 4 to_actors_pedtype 7 // see ped.dat
077A: set_actor 8@ acquaintance 4 to_actors_pedtype 7 // see ped.dat
wait 10
marker.CreateAboveCar(9@,5@)
marker.SetColor(9@,2)
0726: heli 5@ follow_actor $PLAYER_ACTOR follow_car -1 radius 20.0
wait 10
jump to @Heli03

:Heli03
wait 10
if or
00E1:   player 0 pressed_key 15
car.Wrecked(5@)
02BF:   car 5@ sunk
actor.Dead($PLAYER_ACTOR)
jf @Heli04
marker.Disable(9@)
car.RemoveReferences(5@)
actor.RemoveReferences(6@)
actor.RemoveReferences(7@)
actor.RemoveReferences(8@)
wait 10
model.Destroy(#SEASPAR)
model.Destroy(#FAM1)
model.Destroy(#FAM2)
model.Destroy(#AK47)
model.Destroy(#SNIPER)
wait 7500
jump to @Heli01

:Heli04
wait 10
if
actor.Dead(6@)
jf @Heli03
0564: heli 5@ simulate_crash_landing
wait 1500
marker.Disable(9@)
car.RemoveReferences(5@)
actor.RemoveReferences(6@)
actor.RemoveReferences(7@)
actor.RemoveReferences(8@)
wait 10
model.Destroy(#SEASPAR)
model.Destroy(#FAM1)
model.Destroy(#FAM2)
model.Destroy(#AK47)
model.Destroy(#SNIPER)
wait 7500
jump to @Heli01